home *** CD-ROM | disk | FTP | other *** search
/ BBS Toolkit / BBS Toolkit.iso / windows / mrun211.zip / MRUN211C.WAS < prev    next >
Text File  |  1993-05-01  |  24KB  |  915 lines
  1. ;MailRun v2.11:  Part C, changebbs
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This file contains routines related to changing BBS settings.
  9. * Settings are divided into three groups, each with its own
  10. * dialog box:  BBS Settings, BBS Prompts, and Mail Door Prompts.
  11. * The appropriate routine is selected with a FLAG.
  12. * 
  13. **************************************************************************
  14. **************************************************************************
  15. #endcomment
  16.  
  17. #define MRUN211C
  18. #define MRUN211BC
  19.  
  20. #include "mrun211.h"
  21.  
  22. string ProtList, ArcList, MailDoorList, BBSTypeList, BBSChoice
  23.  
  24.  
  25. #comment
  26. *********************************************************************
  27. * 
  28. * MAIN()
  29. * 
  30. * Calls checkchild(), makemaildoorlist(), menudim(),
  31. * makebbstypelist(), makeprotlist(), changeprompts(),
  32. * changeuserinfo(), changemaildoor()
  33. * 
  34. * Dispatches the appropriate command based on the value
  35. * of FLAGS.
  36. * 
  37. *********************************************************************
  38. #endcomment
  39.  
  40. proc main
  41. integer cmdstatus
  42.     menudim()
  43.     checkchild()
  44.     findfirst MailRun
  45.     MailRunTrunc = $FILENAME
  46.     makeprotlist()
  47.     makebbstypelist()
  48.     makemaildoorlist()
  49.     cmdstatus = FLAGS & (USR + PRMPT + QMD)
  50.     switch cmdstatus
  51.         case USR
  52.             changeuserinfo()
  53.         endcase
  54.         case PRMPT
  55.             changeprompts()
  56.         endcase
  57.         case QMD
  58.             changemaildoor()
  59.         endcase
  60.     endswitch
  61. endproc
  62.  
  63.  
  64. #comment
  65. *********************************************************************
  66. * 
  67. * CHANGEUSERINFO()
  68. * 
  69. * Called by main()
  70. * 
  71. * Calls makebbslist(), loadbbsinfo(), loadprompts(), 
  72. * loadmaildoor(), writebbsinfo(), writeprompts(), 
  73. * writemaildoor(), interfaceon(), insertbbs(),
  74. * bbsbox(), addbbs(), defaultsprompts(), defaultsdoor(), 
  75. * cfgprompts(), cfgmaildoor(), checkchanged(),
  76. * gettaskstring()
  77. * 
  78. * Puts up the BBS Information dialog box and allows the
  79. * user to change the values for the current BBS.  If the
  80. * the DEFAULTS flag is set, changes the DEFAULT BBS
  81. * settings.  If the NEW flag is set, calls addbbs().
  82. * 
  83. *********************************************************************
  84. #endcomment
  85.  
  86. proc changeuserinfo
  87. string LastBBS, LastBBSType, BBSid, char
  88. integer dialogstatus, NameChanged, i
  89.     if FLAGS & DEFAULTS
  90.         BBSList = "DEFAULT"
  91.         BBSChoice = "DEFAULT"
  92.         loadbbsinfo(MailRun, "DEFAULT")
  93.         loadprompts(MailRunIni, BBSType)
  94.         loadmaildoor(MailRunIni, MailDoorType)
  95.         findfirst MailRun
  96.         strfmt BBSName "BBS Info Defaults for %s" $FILENAME
  97.     else
  98.         makebbslist()
  99.         strextract BBSChoice TaskItem "`t" 3
  100.         loadbbsinfo(MailRun, BBSChoice)
  101.         loadprompts(MailRun, BBSChoice)
  102.         loadmaildoor(MailRun, BBSChoice)
  103.     endif
  104.     NameChanged = 0
  105.     LastBBS = BBSChoice
  106.     LastBBSType = BBSType
  107.     bbsbox()
  108.     interfaceon()
  109.     FLAGS &= UNCHANGED
  110.     if FLAGS & NEW
  111.         addbbs()
  112.         LastBBS = BBSChoice
  113.     endif
  114.     while 1
  115.         dialogstatus = $DIALOG
  116.         switch dialogstatus
  117.             case 10
  118.                 ;User selected "Prompts"
  119.                 if FLAGS & DEFAULTS
  120.                     defaultsprompts()
  121.                 else
  122.                     cfgprompts()
  123.                 endif
  124.             endcase
  125.             case 11
  126.                 ;User selected "Mail Door"
  127.                 if FLAGS & DEFAULTS
  128.                     defaultsdoor()
  129.                 else
  130.                     cfgmaildoor()
  131.                 endif
  132.             endcase
  133.             case 12
  134.                 ;User selected "Save"
  135.                 if NULLSTR BBSName
  136.                     usermsg "You must enter the name of the BBS!"
  137.                     loopwhile
  138.                 elseif FLAGS & NEW
  139.                     ;if it is a new BBS
  140.                     if not NULLSTR TaskItem
  141.                         ;if there are other BBSs in the mailrun
  142.                         strextract BBSid TaskItem "`t" 3
  143.                         insertbbs(BBSid, BBSChoice)
  144.                     else
  145.                         ;if this is the only BBS in the mailrun
  146.                         writebbs(1, BBSChoice)
  147.                     endif
  148.                     TaskItem = gettaskstring(BBSid, 0)
  149.                     FLAGS &= OLD
  150.                 endif
  151.                 if FLAGS & DEFAULTS
  152.                     writebbsinfo(MailRun, "DEFAULT")
  153.                     writeprompts(MailRunIni, BBSType)
  154.                     writemaildoor(MailRunIni, MailDoorType)
  155.                 else
  156.                     writebbsinfo(MailRun, BBSChoice)
  157.                     writeprompts(MailRun, BBSChoice)
  158.                     writemaildoor(MailRun, BBSChoice)
  159.                 endif
  160.                 strextract char TaskItem "`t" 4
  161.                 atoi char i
  162.                 if NameChanged && !(i)
  163.                     TaskItem = gettaskstring(BBSChoice, 0)
  164.                 endif
  165.                 FLAGS &= UNCHANGED
  166.             endcase
  167.             case 13
  168.                 ;User selected "Done:
  169.                 if checkchanged()
  170.                     exit
  171.                 endif
  172.             endcase
  173.             case 171
  174.                 ;User changed the BBS type
  175.                 if FLAGS & DEFAULTS
  176.                     if checkchanged()
  177.                         loadprompts(MailRunIni, BBSType)
  178.                         FLAGS &= UNCHANGED
  179.                         LastBBSType = BBSType
  180.                     else
  181.                         BBSType = LastBBSType
  182.                     endif
  183.                 else
  184.                     loadprompts(MailRunIni, BBSType)
  185.                 endif
  186.                 FLAGS |= CHANGED
  187.                 updatedlg -1
  188.             endcase
  189.             case 172
  190.                 ;User changed the mail door type
  191.                 if FLAGS & DEFAULTS
  192.                     loadmaildoor(MailRunIni, MailDoorType)
  193.                 else
  194.                     loadmaildoor(MailRunIni, MailDoorType)
  195.                 endif
  196.                 FLAGS |= CHANGED
  197.             endcase
  198.             case 173
  199.                 ;User changed BBS ID with combobox
  200.                 if checkchanged()
  201.                     loadbbsinfo(MailRun, BBSChoice)
  202.                     loadprompts(MailRun, BBSChoice)
  203.                     loadmaildoor(MailRun, BBSChoice)
  204.                     TaskItem = gettaskstring(BBSChoice, 0)
  205.                     FLAGS &= UNCHANGED
  206.                     LastBBS = BBSChoice
  207.                     updatedlg -1
  208.                 else
  209.                     BBSChoice = LastBBS
  210.                     updatedlg 512
  211.                 endif
  212.             endcase
  213.             case 230
  214.                 NameChanged = 1
  215.                 FLAGS |= CHANGED
  216.             endcase
  217.             case 70
  218.             case 170
  219.             case 231
  220.             case 232
  221.             case 233
  222.             case 234
  223.             case 235
  224.             case 236
  225.             case 237
  226.             case 238
  227.             case 239
  228.                 FLAGS |= CHANGED
  229.             endcase
  230.         endswitch
  231.     endwhile
  232. endproc
  233.  
  234.  
  235. #comment
  236. *********************************************************************
  237. * 
  238. * CHANGEPROMPTS()
  239. * 
  240. * Called by main()
  241. * 
  242. * Calls makebbslist(), promptbox(), loadprompts(),
  243. * writeprompts(), interfaceon(), defaultsbbs(), defaultsdoor(),
  244. * cfgbbs(), cfgmaildoor(), exportprompts(), checkchanged(),
  245. * gettaskstring()
  246. * 
  247. * Allows the user to change the prompts for a given BBS in
  248. * the *.MRN file.  If DEFAULTS flag is set, changes default
  249. * prompts for the current BBS type.
  250. * 
  251. *********************************************************************
  252. #endcomment
  253.  
  254. proc changeprompts
  255. string LastBBS, LastBBSType
  256. integer dialogstatus
  257.     if FLAGS & DEFAULTS
  258.         BBSList = "DEFAULT"
  259.         BBSChoice = "DEFAULT"
  260.         profilerd MailRun "DEFAULT" "BBSType" BBSType
  261.         loadprompts(MailRunIni, BBSType)
  262.     else
  263.         makebbslist()
  264.         strextract BBSChoice TaskItem "`t" 3
  265.         profilerd MailRun BBSChoice "BBSType" BBSType
  266.         loadprompts(MailRun, BBSChoice)
  267.     endif
  268.     LastBBS = BBSChoice
  269.     LastBBSType = BBSType
  270.     promptbox()
  271.     FLAGS &= UNCHANGED
  272.     interfaceon()
  273.     while 1
  274.         dialogstatus = $DIALOG
  275.         switch dialogstatus
  276.             case 10
  277.                 ;User selected "BBS Info"
  278.                 if FLAGS & DEFAULTS
  279.                     defaultsbbs()
  280.                 else
  281.                     cfgbbs()
  282.                 endif
  283.             endcase
  284.             case 11
  285.                 ;User selected "Mail Door"
  286.                 if FLAGS & DEFAULTS
  287.                     defaultsdoor()
  288.                 else
  289.                     cfgmaildoor()
  290.                 endif
  291.             endcase
  292.             case 12
  293.                 ;User selected "Export"
  294.                 exportprompts()
  295.             endcase
  296.             case 13
  297.                 ;User selected "Save"
  298.                 if FLAGS & DEFAULTS
  299.                     writeprompts(MailRunIni, BBSType)
  300.                 else
  301.                     writeprompts(MailRun, BBSChoice)
  302.                     profilewr MailRun BBSChoice "BBSType" BBSType
  303.                 endif
  304.                 FLAGS &= UNCHANGED
  305.             endcase
  306.             case 14
  307.                 ;User selected "Done"
  308.                 if checkchanged()
  309.                     exit
  310.                 endif
  311.             endcase
  312.             case 170
  313.                 ;User changed BBS with the combobox
  314.                 if checkchanged()
  315.                     loadprompts(MailRun, BBSChoice)
  316.                     profilerd MailRun BBSChoice "BBSType" BBSType
  317.                     TaskItem = gettaskstring(BBSChoice, 0)
  318.                     LastBBS = BBSChoice
  319.                     updatedlg -1
  320.                 else
  321.                     BBSChoice = LastBBS
  322.                     updatedlg 512
  323.                 endif
  324.             endcase
  325.             case 171
  326.                 ;User changed BBS type
  327.                 if FLAGS & DEFAULTS
  328.                     if checkchanged()
  329.                         loadprompts(MailRunIni, BBSType)
  330.                         updatedlg 128
  331.                         FLAGS &= UNCHANGED
  332.                         LastBBSType = BBSType
  333.                     else
  334.                         BBSType = LastBBSType
  335.                         updatedlg 512
  336.                     endif
  337.                 else
  338.                     loadprompts(MailRunIni, BBSType)
  339.                     updatedlg 128
  340.                     FLAGS |= CHANGED
  341.                 endif
  342.             endcase
  343.             case 230
  344.             case 231
  345.             case 232
  346.             case 233
  347.             case 234
  348.             case 235
  349.             case 236
  350.             case 237
  351.             case 238
  352.             case 239
  353.             case 240
  354.             case 241
  355.             case 242
  356.             case 243
  357.             case 244
  358.             case 245
  359.                 FLAGS |= CHANGED
  360.             endcase
  361.         endswitch
  362.     endwhile
  363. endproc
  364.  
  365.  
  366. #comment
  367. *********************************************************************
  368. * 
  369. * CHANGEMAILDOOR()
  370. * 
  371. * Called by main()
  372. * 
  373. * Calls makebbslist(), interfaceon(),
  374. * loadmaildoor(), writemaildoor(),
  375. * maildoorbox(), defaultsbbs(), defaultsprompts(),
  376. * cfgbbs(), cfgprompts(), exportmaildoor(), checkchanged(),
  377. * gettaskstring()
  378. * 
  379. * Allows the user to change the mail door prompts for a
  380. * given BBS in the *.MRN file.
  381. * 
  382. *********************************************************************
  383. #endcomment
  384.  
  385. proc changemaildoor
  386. string LastBBS, LastDoorType
  387. integer dialogstatus
  388.     if FLAGS & DEFAULTS
  389.         BBSList = "DEFAULT"
  390.         BBSChoice = "DEFAULT"
  391.         profilerd MailRun "DEFAULT" "MailDoorType" MailDoorType
  392.         loadmaildoor(MailRunIni, MailDoorType)
  393.     else
  394.         makebbslist()
  395.         strextract BBSChoice TaskItem "`t" 3
  396.         profilerd MailRun BBSChoice "MailDoorType" MailDoorType
  397.         loadmaildoor(MailRun, BBSChoice)
  398.     endif
  399.         profilerd MailRun BBSChoice "QWKArchiver" QWKArchiver
  400.         profilerd MailRun BBSChoice "MailXferProt" MailXferProt
  401.     LastBBS = BBSChoice
  402.     LastDoorType = MailDoorType
  403.     ArcList = "arj.exe,fpzipx.exe,lha.exe,lharc.exe,pkunzip.exe,pkxarc.exe,zoo.exe"
  404.     maildoorbox()
  405.     interfaceon()
  406.     while 1
  407.         dialogstatus = $DIALOG
  408.         switch dialogstatus
  409.             case 10
  410.                 ;User selected "Prompts"
  411.                 if FLAGS & DEFAULTS
  412.                     defaultsprompts()
  413.                 else
  414.                     cfgprompts()
  415.                 endif
  416.             endcase
  417.             case 11
  418.                 ;User selected "BBS Info"
  419.                 if FLAGS & DEFAULTS
  420.                     defaultsbbs()
  421.                 else
  422.                     cfgbbs()
  423.                 endif
  424.             endcase
  425.             case 12
  426.                 ;User selected "Export"
  427.                 exportmaildoor()
  428.             endcase
  429.             case 13
  430.                 ;User selected "Save"
  431.                 if FLAGS & DEFAULTS
  432.                     writemaildoor(MailRunIni, MailDoorType)
  433.                 else
  434.                     writemaildoor(MailRun, BBSChoice)
  435.                     profilewr MailRun BBSChoice "MailDoorType" MailDoorType
  436.                 endif
  437.                 profilewr MailRun BBSChoice "QWKArchiver" QWKArchiver
  438.                 profilewr MailRun BBSChoice "MailXferProt" MailXferProt
  439.                 FLAGS &= UNCHANGED
  440.             endcase
  441.             case 14
  442.                 ;User selected "Done"
  443.                 if checkchanged()
  444.                     exit
  445.                 endif
  446.             endcase
  447.             case 170
  448.                 ;User changed mail door type
  449.                 if FLAGS & DEFAULTS
  450.                     if checkchanged()
  451.                         loadmaildoor(MailRunIni, MailDoorType)
  452.                         FLAGS &= UNCHANGED
  453.                         updatedlg 128
  454.                         LastDoorType = MailDoorType
  455.                     else
  456.                         MailDoorType = LastDoorType
  457.                         updatedlg 512
  458.                     endif
  459.                 else
  460.                     loadmaildoor(MailRunIni, MailDoorType)
  461.                     FLAGS |= CHANGED
  462.                     updatedlg 128
  463.                 endif
  464.             endcase
  465.             case 173
  466.                 ;User changed the current BBS
  467.                 if checkchanged()
  468.                     loadmaildoor(MailRun, BBSChoice)
  469.                     profilerd MailRun BBSChoice "MailDoorType" MailDoorType
  470.                     profilerd MailRun BBSChoice "QWKArchiver" QWKArchiver
  471.                     profilerd MailRun BBSChoice "MailXferProt" MailXferProt
  472.                     TaskItem = gettaskstring(BBSChoice, 0)
  473.                     LastBBS = BBSChoice
  474.                     updatedlg -1
  475.                 else
  476.                     BBSChoice = LastBBS
  477.                     updatedlg 512
  478.                 endif
  479.             endcase
  480.             case 171
  481.             case 172
  482.             case 230
  483.             case 231
  484.             case 232
  485.             case 233
  486.             case 234
  487.             case 235
  488.                 FLAGS |= CHANGED
  489.             endcase
  490.         endswitch
  491.     endwhile
  492. endproc
  493.                 
  494.  
  495. #comment
  496. *********************************************************************
  497. * 
  498. * ADDBBS()
  499. * 
  500. * Called by changeuserinfo()
  501. * 
  502. * Calls fverify(), inlist(), loadbbsinfo(), loadprompts(), 
  503. * loadmaildoor()
  504. * 
  505. * Adds a BBS to the *.MRN file, assigning default info
  506. * and prompts.
  507. * 
  508. *********************************************************************
  509. #endcomment
  510.  
  511. proc addbbs
  512. string NewBBS
  513.     while 1
  514.         sdlginput "BBS ID" "Enter the ID of the BBS:" NewBBS
  515.         if FAILURE
  516.             exit 
  517.         endif
  518.         strlwr NewBBS
  519.         if not fverify(NewBBS)
  520.             usermsg "A bulletin board's BBS ID is the same as the \
  521. name of it's QWK packet.  It must be a valid DOS \
  522. file name without the extension."
  523.         elseif inlist(NewBBS, BBSList) 
  524.             errormsg "That BBS is already in the MailRun!"
  525.         else
  526.             exitwhile
  527.         endif
  528.     endwhile
  529.  
  530.     ;If there is no previously existing information for the new BBS,
  531.     ;assign the defaults, otherwise, use the old info.
  532.     ;Any previously entered BBS will have a name.
  533.  
  534.     profilerd MailRun NewBBS "BBSName" BBSName
  535.     if NULLSTR BBSName
  536.         ;Load defaults
  537.         loadbbsinfo(MailRun, "DEFAULT")
  538.         loadprompts(MailRunIni, BBSType)
  539.         loadmaildoor(MailRunIni, MailDoorType)
  540.         BBSName = ""
  541.         FLAGS &= (ALLFLAGS - DEFAULTS)
  542.     else
  543.         loadbbsinfo(MailRun, NewBBS)
  544.         loadprompts(MailRun, NewBBS)
  545.         loadmaildoor(MailRun, NewBBS)
  546.     endif
  547.     FLAGS |= CHANGED
  548.     ;Add the new BBS to the BBS list
  549.     if not NULLSTR BBSList
  550.         strfmt BBSList "%s,%s" BBSList NewBBS
  551.     else
  552.         BBSList = NewBBS
  553.     endif
  554.     BBSChoice = NewBBS
  555.     updatedlg -1
  556. endproc
  557.  
  558.  
  559. #comment
  560. *********************************************************************
  561. * 
  562. * EXPORTPROMPTS()
  563. * 
  564. * Called by changeprompts()
  565. * 
  566. * Calls findstring(), writeprompts(), makebbstypelist(),
  567. * inlist()
  568. * 
  569. * Creates a new BBS type with current prompt set.
  570. * 
  571. *********************************************************************
  572. #endcomment
  573.  
  574. proc exportprompts
  575. string NewBBSType, BBSType_X
  576. integer i
  577.     while 1
  578.         NewBBSType = BBSType
  579.         sdlginput "Export Prompts" "Name the new prompt set:" \
  580.             NewBBSType DEFAULT
  581.         if FAILURE
  582.             return
  583.         endif
  584.         if inlist(NewBBSType, BBSTypeList) 
  585.             usermsg "There is already a prompt set for %s!" NewBBSType
  586.             loopwhile
  587.         endif
  588.         if !(findstring(NewBBSType "PCBoard") || \
  589.             findstring(NewBBSType, "WildCat") || \
  590.             findstring(NewBBSType, "Auntie") || findstring(NewBBSType, "RBBS"))
  591.             usermsg "The name of the prompt set must contain a \
  592. keyword indicating the type of BBS.  Valid keywords are `"PCBoard,`" \
  593. `"WildCat,`" `"RBBS`" and `"Auntie.`""
  594.             loopwhile
  595.         endif
  596.         exitwhile
  597.     endwhile
  598.     i = 1
  599.     strfmt BBSType_X "BBSType_%d" i
  600.     profilerd MailRunIni "BBSTypes" BBSType_X BBSType
  601.     while not NULLSTR BBSType
  602.         i++
  603.         strfmt BBSType_X "BBSType_%d" i
  604.         profilerd MailRunIni "BBSTypes" BBSType_X BBSType
  605.     endwhile
  606.     BBSType = NewBBSType
  607.     profilewr MailRunIni "BBSTypes" BBSType_X BBSType
  608.     writeprompts(MailRunIni, BBSType)
  609.     makebbstypelist()
  610.     updatedlg 512
  611. endproc
  612.  
  613.  
  614. #comment
  615. *********************************************************************
  616. * 
  617. * EXPORTMAILDOOR()
  618. * 
  619. * Called by changemaildoor()
  620. * 
  621. * Calls writemaildoor(), makemaildoorlist(), inlist()
  622. * 
  623. * Adds a BBS to the *.MRN file, assigning default info
  624. * and prompts.
  625. * 
  626. *********************************************************************
  627. #endcomment
  628.  
  629. proc exportmaildoor
  630. string NewMailDoorType, MailDoor_X
  631. integer i
  632.     while 1
  633.         NewMailDoorType = MailDoorType
  634.         sdlginput "Export Prompts" "Name the new mail door:" \
  635.             NewMailDoorType DEFAULT
  636.         if FAILURE
  637.             return
  638.         endif
  639.         if inlist(NewMailDoorType, MailDoorList) 
  640.             usermsg "There is already a prompt set for %s!" \
  641.                 NewMailDoorType
  642.             loopwhile
  643.         endif
  644.         exitwhile
  645.     endwhile
  646.     i = 1
  647.     strfmt MailDoor_X "MailDoor_%d" i
  648.     profilerd MailRunIni "MailDoors" MailDoor_X MailDoorType
  649.     while not NULLSTR MailDoorType
  650.         i++
  651.         strfmt MailDoor_X "MailDoor_%d" i
  652.         profilerd MailRunIni "MailDoors" MailDoor_X MailDoorType
  653.     endwhile
  654.     MailDoorType = NewMailDoorType
  655.     profilewr MailRunIni "MailDoors" MailDoor_X MailDoorType
  656.     writemaildoor(MailRunIni, MailDoorType)
  657.     makemaildoorlist()
  658.     updatedlg 512
  659. endproc
  660.  
  661.  
  662. #comment
  663. *********************************************************************
  664. * 
  665. * BBSBOX()
  666. * 
  667. * Called by changeuserinfo()
  668. * 
  669. * Displays the BBS Information dialog box.
  670. * 
  671. *********************************************************************
  672. #endcomment
  673.  
  674. proc bbsbox
  675. destroydlg
  676. HelpPage = 5
  677. dialogbox 24 36 320 215 15 "BBS Information" helpid HelpPage
  678.    text  142 10 40 8 right "BBS Name:"
  679.    editbox 186 8 121 12 BBSName
  680.    groupbox 10 28 138 156 "BBS Info" shadow
  681.    text  13 47 62 8 right "User ID:"
  682.    text  13 67 62 8 right "Password:"
  683.    text  13 87 62 8 right "Xfer Protocol:"
  684.    text  13 107 62 11 right "Calling From:"
  685.    text  13 127 62 8 right "User Response 1:"
  686.    text  13 147 62 8 right "User Response 2:"
  687.    text  27 167 92 8 right "Language/Prompt Scheme:"
  688.    editbox 79 45 60 12 UserName
  689.    editbox 79 65 60 12 PWord
  690.    combobox 79 85 60 42 ProtList XferProt sort
  691.    editbox 79 105 60 12 CallingFrom
  692.    editbox 79 125 60 12 UserResp1
  693.    editbox 79 145 60 12 UserResp2
  694.    editbox 123 165 16 12 LangNumber
  695.    checkbox 187 174 90 12 "Display ANSI Graphics " GraphicsOn
  696.    groupbox 158 29 150 79 "Phone Numbers" shadow
  697.    text  162 49 35 8 right "Node 1:"
  698.    text  162 69 35 8 right "Node 2:"
  699.    text  162 89 35 8 right "Node 3:"
  700.    editbox 201 47 100 12 Number_1
  701.    editbox 201 67 100 12 Number_2
  702.    editbox 201 87 100 12 Number_3
  703.    groupbox 158 115 150 50 shadow
  704.    text  160 128 39 8 right "BBS Type:"
  705.    text  171 145 39 8 right "Mail Door:"
  706.    combobox 202 124 98 42 BBSTypeList BBSType sort
  707.    combobox 214 143 76 42 MailDoorList MailDoorType sort
  708.    pushbutton 42 193 52 14 "&Prompts" normal
  709.    pushbutton 104 193 52 14 "&Mail Door" normal
  710.    pushbutton 169 193 52 14 "&Save" normal default
  711.    pushbutton 232 193 52 14 "&Done" normal
  712.    text  28 10 36 8 right "BBS ID:"
  713.    combobox 68 8 66 42 BBSList BBSChoice sort
  714. enddialog
  715. endproc
  716.  
  717.  
  718. #comment
  719. *********************************************************************
  720. * 
  721. * PROMPTBOX()
  722. * 
  723. * Called by changeprompts()
  724. * 
  725. * Displays the BBS Prompts dialog box.
  726. * 
  727. *********************************************************************
  728. #endcomment
  729.  
  730. proc promptbox
  731. destroydlg
  732. HelpPage = 6
  733. dialogbox 14 36 324 209 15 "BBS Prompts" HELPID HelpPage
  734.    groupbox 13 30 297 147 shadow
  735.    text  18 44 56 8 right "Language:"
  736.    text  18 60 56 8 right "ANSI Graphics:"
  737.    text  18 76 56 8 right "Name:"
  738.    text  18 92 56 8 right "Password:"
  739.    text  18 108 56 8 right "User Prompt 1:"
  740.    text  18 124 56 8 right "User Prompt 2:"
  741.    text  18 140 56 8 right "View:"
  742.    text  18 156 56 8 right "Scan Msg Base:"
  743.    editbox 78 42 76 12 LangPrompt
  744.    editbox 78 58 76 12 GraphicsPrompt
  745.    editbox 78 74 76 12 NamePrompt
  746.    editbox 78 90 76 12 PWordPrompt
  747.    editbox 78 106 76 12 UserPrompt1
  748.    editbox 78 122 76 12 UserPrompt2
  749.    editbox 78 138 76 12 ViewPrompt
  750.    editbox 78 154 76 12 ScanPrompt
  751.    text  160 44 56 8 right "File Prompt:"
  752.    text  160 60 56 8 right "More:"
  753.    text  160 76 56 8 right "Continue:"
  754.    text  160 92 56 8 right "Command:"
  755.    text  160 108 56 8 right "File Unavailable:"
  756.    text  160 124 56 8 right "File Description:"
  757.    text  160 140 56 8 right "Start File D/L:"
  758.    text  160 156 56 8 right "Start File U/L:"
  759.    editbox 220 42 76 12 FilePrompt
  760.    editbox 220 58 76 12 MorePrompt
  761.    editbox 220 74 76 12 ContinuePrompt
  762.    editbox 220 90 76 12 CommandPrompt
  763.    editbox 220 106 76 12 DLUnavPrompt
  764.    editbox 220 122 76 12 ULDescPrompt
  765.    editbox 220 138 76 12 DLPrompt
  766.    editbox 220 154 76 12 ULPrompt
  767.    pushbutton 22 187 48 14 "&BBS Info" normal
  768.    pushbutton 80 187 48 14 "&Mail Door" normal
  769.    pushbutton 138 187 48 14 "&Export" normal
  770.    pushbutton 196 187 48 14 "&Save" normal default
  771.    pushbutton 254 187 48 14 "&Done" normal
  772.    text  12 14 42 8 right "Prompts for:"
  773.    combobox 58 12 72 42 BBSList BBSChoice sort
  774.    text  134 14 68 8 right "Prompts based on:"
  775.    combobox 206 12 100 42 BBSTypeList BBSType sort
  776. enddialog
  777. endproc
  778.  
  779.  
  780. #comment
  781. *********************************************************************
  782. * 
  783. * MAILDOORBOX()
  784. * 
  785. * Called by changemaildoor()
  786. * 
  787. * Displays the Mail Door dialog box.
  788. * 
  789. *********************************************************************
  790. #endcomment
  791.  
  792. proc maildoorbox
  793. destroydlg
  794. HelpPage = 7
  795. dialogbox 8 36 342 165 15 "Mail Door" helpid HelpPage
  796.    groupbox 12 33 156 93 shadow
  797.    text  20 48 62 8 right "Start Mail Door:"
  798.    text  20 68 62 8 right "Prompts Based on:"
  799.    text  20 88 62 8 right "QWK Archiver:"
  800.    text  20 108 62 8 right "Transfer Protocol:"
  801.    editbox 86 46 70 12 MailDoor
  802.    combobox 86 66 70 42 MailDoorList MailDoorType sort
  803.    combobox 86 86 70 42 ArcList QWKArchiver sort
  804.    combobox 86 106 70 42 ProtList MailXferProt sort
  805.    groupbox 180 11 150 115 "Prompts" shadow
  806.    text  190 28 56 8 right "Message Menu:"
  807.    text  190 48 56 8 right "Mail Command:"
  808.    text  190 68 56 8 right "Receive Packet:"
  809.    text  190 88 56 8 right "Start Mail U/L:"
  810.    text  190 108 56 8 right "Start Mail D/L:"
  811.    editbox 250 25 70 12 MsgMenuPrompt
  812.    editbox 250 46 70 12 MailPrompt
  813.    editbox 250 66 70 12 ReceiveQWKPrompt
  814.    editbox 250 86 70 12 MailULPrompt
  815.    editbox 250 106 70 12 MailDLPrompt
  816.    text  19 13 53 8 right "Mail Door for:"
  817.    combobox 76 11 77 42 BBSList BBSChoice sort
  818.    pushbutton 22 139 50 14 "&Prompts" normal
  819.    pushbutton 84 139 50 14 "&BBS Info" normal
  820.    pushbutton 146 139 50 14 "&Export" normal
  821.    pushbutton 208 139 50 14 "&Save" normal default
  822.    pushbutton 270 139 50 14 "&Done" normal
  823. enddialog
  824. endproc
  825.  
  826.  
  827. #comment
  828. *********************************************************************
  829. * 
  830. * MAKEPROTLIST()
  831. * 
  832. * Called by main()
  833. * 
  834. * Creates a list of transfer protocols for display in the
  835. * bbsbox() dialog box protocol combobox.
  836. * 
  837. *********************************************************************
  838. #endcomment
  839.  
  840. proc makeprotlist
  841. string ProtName
  842. integer i
  843.     i = 0
  844.     ProtList = ""
  845.     getitem PROTOCOL i ProtName
  846.     while not NULLSTR ProtName
  847.         strfmt ProtList "%s,%s" ProtList ProtName
  848.         i++
  849.         getitem PROTOCOL i ProtName
  850.     endwhile
  851.     strdelete ProtList 0 1
  852. endproc
  853.  
  854.  
  855. #comment
  856. *********************************************************************
  857. * 
  858. * MAKEMAILDOORLIST()
  859. * 
  860. * Called by main(), exportmaildoor()
  861. * 
  862. * Creates a list of mail doors for display the mail door
  863. * combobox of the BBS info and Mail Door dialog boxes.
  864. * 
  865. *********************************************************************
  866. #endcomment
  867.  
  868. proc makemaildoorlist
  869. string MailDoor_X, DoorType
  870. integer i
  871.     MailDoorList = ""
  872.     i = 1
  873.     profilerd MailRunIni "MailDoors" "MailDoor_1" DoorType
  874.     while not NULLSTR DoorType
  875.         strfmt MailDoorList "%s,%s" MailDoorList DoorType
  876.         i++
  877.         strfmt MailDoor_X "MailDoor_%d" i
  878.         profilerd MailRunIni "MailDoors" MailDoor_X DoorType
  879.     endwhile
  880.     if i > 1
  881.         strdelete MailDoorList 0 1
  882.     endif
  883. endproc
  884.  
  885.  
  886. #comment
  887. *********************************************************************
  888. * 
  889. * MAKEBBSTYPELIST()
  890. * 
  891. * Called by main(), exportprompts()
  892. * 
  893. * Creates a list of BBS types for display the BBS type
  894. * combobox of the BBS info and BBS prompt dialog boxes.
  895. * 
  896. *********************************************************************
  897. #endcomment
  898.  
  899. proc makebbstypelist
  900. string BBSType_X, BoardType
  901. integer i
  902.     BBSTypeList = ""
  903.     i = 1
  904.     profilerd MailRunIni "BBSTypes" "BBSType_1" BoardType
  905.     while not NULLSTR BoardType
  906.         strfmt BBSTypeList "%s,%s" BBSTypeList BoardType
  907.         i++
  908.         strfmt BBSType_X "BBSType_%d" i
  909.         profilerd MailRunIni "BBSTypes" BBSType_X BoardType
  910.     endwhile
  911.     if i > 1
  912.         strdelete BBSTypeList 0 1
  913.     endif
  914. endproc
  915.